;IPAP-[15N,1H]-HSQC (1H-coupled in F1(N))
;
;Reference:
;Ottiger, M., Delaglio, F. & Bax, A. 
;J. Magn. Reson. 131, 373-378 (1998)
;
;needed files:
;Gradnt_new.incl        standard Bruker include file
;FQ2LIST                frequency list (CA - CO)

#include "Gradnt.incl"

#define CARBON_LABEL   ; uncomment if also 13C labelled
;#define CALIBRATE	; uncomment to calibrate N15 hard 90

;Pulse definitions:
;p1     proton 90 at pl1
;p9     proton 90 for WATERGATE at pl9 (~42 dB) adjust phcor14!
;p5*2	carbon 180 at pl5 null excitation @120.5ppm (p5 is ~28.6u @ 500 MHz)
;p2     nitrogen 90 at pl2
;pcpd2	nitrogen 90 at pl12 for decoupling (cpdprg2 is WALTZ16)

;Gradient pulses (may have to be set manually):
"p20=2.0m"      
"p11=1.0m"
"p14=0.4m"

#ifdef CARBON_LABEL
"d0=in0*0.5-4u-p5*2.0-p2*0.63"  ;nitrogen incremental delay
#else
"d0=in0*0.5 - p2*0.63 -p1"
#endif

#ifdef CALIBRATE
"p17=2*p2"  ;should give null signal for p2 exactly 90 degrees
#else
"p17=p2"
#endif


"d3=2.3m"               ;1/4JNH  * 0.85
"d4=d3-p14-2u"  
"d5=d3-p14-p9-14u"
"d11=50u"               ;write delay
"d12=10u"               ;increment delay
"d13=25m"
"d22=p9"
"d23=p3"
"d24=p17*1.26 -p1"
"d25=p1*2"
"d26=p2-p1"




1       ze
        10u ru2
2       d11 do:N
        d12
3       d12*3
4       d12*3
5       10u do:C1
        10u pl5:C1 
        10u pl2:N
#ifdef CARBON_LABEL
        10u fq3:C1      ;jump to 56ppm
#endif
        d1
        1m LOCK_OFF
        10u pl1:H 
        10u pl5:C1
        (p2 ph0):N         ;eliminate Boltzmann
        p20:gp3
        3m
        (p1 ph0)
        2u
        p14:gp5
        d4
        (p2*2 ph6):N (d26 p1*2 ph0)
        2u
        p14:gp5
        d4
;------------- start INEPT to 15N -----------------------
        (p1 ph6)
        2u
        4u pl9:H
        p20:gp0
        1m pl1:H
        (p17 ph3):N
        if "l2==1" goto 20
        1m  ;p23:gp3
        1.7m
        (p2*2 ph5):N (d26 p1*2 ph0):H
        1m  ;p23:gp3
        1.7m
        d24
        (p1 ph4):H
20      d0 pl5:C1
#ifdef CARBON_LABEL
        2u
        (p5*2 ph10):C1  ;(p1*2 ph0):H
        2u
        4u fq3:C1       ;jump to 177ppm
        (p5*2 ph10):C1
#else
        d25  ;  (p1*2 ph0)   ;no 180 for F1-coupled spectrum
#endif
        d0
        if "l2==2"goto 40
        (p2 ph7):N
        goto 41
40      (p2 ph17):N
41      2u
        p11:gp1
        2m pl1:H
;------------- INEPT back to H, WATERGATE ---------------
        (p1 ph0)
        5u
        p14:gp0
        d5 pl9:H
        2u
        (p9 ph14:r)
        2u
        5u pl1:H
        (p1*2 ph15)
        2u
        5u pl9:H
        (p2*2 ph10):N (p9 ph14:r)
        2u
        p14:gp0
        d5 ph0
        5u pl12:N
        go=2 ph31 cpd2:N
        d11 wr #0 if #0 zd
        1m LOCK_ON
        10u do:N
        d12 iu2
     lo to 3 times 2
        d12 ru2
        d12 dp7
        d12 dp17
     lo to 4 times 2
        d12 id0
        d12 ip31
        d12 ip31
        lo to 5 times l3
        d12 do:C1
        d12 do:N
        1m LOCK_ON
        100u RESET
        exit

ph0=0
ph1=0
ph3=0 0 2 2
ph4=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph5=0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph6=1 3
ph7=0
ph17=1 1 1 1 3 3 3 3
ph10=0
ph14=2
;ph14=(3600)1756
ph15=0
ph31=0 2 2 0